# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libxmlrpc
pkgver=1.51.08
pkgrel=1
epoch=1
pkgdesc="XML-RPC for C and C++"
arch=('i686' 'x86_64')
url='http://xmlrpc-c.sourceforge.net/'
license=('Modified-BSD' 'Expat' 'GPL-1' 'Python-CWI')
depends=('curl')
makedepends=('libtool' 'setconf')
conflicts=('xmlrpc-c')
provides=('xmlrpc-c')
replaces=('xmlrpc-c')
options=(!emptydirs)
source=("https://downloads.sourceforge.net/project/xmlrpc-c/Xmlrpc-c%20Super%20Stable/$pkgver/xmlrpc-$pkgver.tgz")
sha512sums=('df0d8e3730b529fb10fb2cf9511dc55143ad3c7b4cce5522b61ed0d212080f3ebf4b6aa8a28911ddbe90029fce6bea7df28ee51f36196900a855beff5bd3a1cd')

build() {
  cd xmlrpc-$pkgver

  ./configure \
    --disable-cgi-server \
    --disable-libwww-client \
    --disable-libxml2-backend \
    --disable-wininet-client \
    --enable-cplusplus \
    --mandir=/usr/share/man \
    --prefix=/usr

  mkdir -p include/curl
  touch include/curl/types.h

  make CFLAGS_PERSONAL="$CFLAGS -fPIC -w" CXXFLAGS_PERSONAL="$CXXFLAGS -fPIC -w"
  make -C tools CFLAGS_PERSONAL="$CFLAGS -fPIC -w" CXXFLAGS_PERSONAL="$CXXFLAGS -fPIC -w"
}

package() {
  cd xmlrpc-$pkgver

  make DESTDIR="$pkgdir" install
  make DESTDIR="$pkgdir" -C tools install

  # remove references to build directory
  setconf "$pkgdir/usr/bin/xmlrpc-c-config" BLDDIR ''
  setconf "$pkgdir/usr/bin/xmlrpc-c-config" ABS_SRCDIR ''

  # license
  install -Dm644 doc/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}