# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libxklavier
pkgver=5.4
_debver=$pkgver
_debrel=4
pkgrel=1
pkgdesc="High-level API for X Keyboard Extension"
url='https://www.freedesktop.org/wiki/Software/LibXklavier/'
arch=('i686' 'x86_64')
license=('LGPL-2')
depends=('glib2' 'libxkbfile' 'libxml2' 'xkeyboard-config' 'libxi' 'iso-codes')
makedepends=('gobject-introspection' 'intltool' 'quilt' 'libxfixes')
options=('!emptydirs')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/libx/libxklavier/libxklavier_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/libx/libxklavier/libxklavier_${_debver}-${_debrel}.debian.tar.xz"
        "remove-gtk-doc.patch")
sha512sums=('d5ebcaca76b47651e2f64a8e3aa1b186da81d88aa471293823827e397b17d5851489417574609bcded6bd8cfc0a1967d933e8b6a53fe61054dd891c3b695a1f0'
            '594c2263daa33d357d28a5123c32cd79293cbed6e190944c37af0f91fb7e92c6315b812622bb2758f5027aaf76ed02baff43ef59a1b0ee8babb8063faa75d005'
            '5073c9650fb1b3f7c74e9f5da5f1b320d6afedaed8520354ae2ad097cf636147de8ee76713b8df602c72897ce6600b20a6522a5c2fcb0323547694b81eed1ac3')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  rm -rf ./doc
  patch -Np1 -i ${srcdir}/remove-gtk-doc.patch
  autoreconf -vi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --with-xkb-bin-base=/usr/bin \
    --with-xkb-base=/usr/share/X11/xkb \
    --disable-static \
    --disable-gtk-doc
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING.LIB -t "$pkgdir"/usr/share/licenses/$pkgname
}