# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libunwind
pkgver=1.3.2
_debver=1.3.2
_debrel=2
pkgrel=1
pkgdesc='Portable and efficient C programming interface (API) to determine the call-chain of a program'
arch=('i686' 'x86_64')
url='https://www.nongnu.org/libunwind/'
license=('Expat')
depends=('glibc' 'xz')
makedepends=('quilt')
source=("https://download.savannah.gnu.org/releases/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig}
        "https://deb.debian.org/debian/pool/main/libu/libunwind/libunwind_$_debver-$_debrel.debian.tar.xz")
sha512sums=('221864eae6bf0fde281d9551662af1e539ce919fbb7050947e60dbcc09efed4f5d34574dbce11792513e63151e0af72f02801b7bcd37a6a519e6d868abb8b509'
            'SKIP'
            '48dcc63be16ea1ca11dc2d05e0b33746385b19cb453ed7a1e967b32ae5906e1f851ef67d7a341522372f38ec296ffea107f58830c0690ba934824cc75500c768')
validpgpkeys=('75D2CFC56CC2E935A4143297015A268A17D55FA4') # Dave Watson

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

check() {
  cd $pkgname-$pkgver
  # This function is ``supposed'' to fail. Upstream know, but haven't fixed it.
  make check || :
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}

# vim:set ts=2 sw=2 et: