# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libtar
pkgver=1.2.20
_debver=1.2.20
_debrel=8
pkgrel=1
pkgdesc='C library for manipulating POSIX tar files'
arch=('i686' 'x86_64')
url='https://github.com/tklauser/libtar'
license=('Modified-BSD')
depends=('zlib')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/tklauser/libtar/archive/refs/tags/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libt/libtar/libtar_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('11a12695abf4f9668801d24b7b552daed1219b2f395c09818d15e16721f7136d63aa0c09e442401e4fedbf7335748f0dc46f8da21b94b36595910b2fe44d4aea'
            'db2e29c89e77ae77429b0506adbd7b8191eadbf3a3a1328508c04f5b0dc68552084edc3abe0f24689baa02ca05f65dc8698f557031a3377fe384bad4e95b7f4d')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  autoreconf -vfi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --disable-static \
    --disable-encap \
    --disable-epkg-install
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${pkgname}
}