# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libssh
pkgver=0.9.8
_debver=$pkgver
_debrel=0
pkgrel=1
pkgdesc="Library for accessing ssh client services through C libraries"
url='https://www.libssh.org/'
license=('LGPL-2.1')
arch=('i686' 'x86_64')
depends=('zlib' 'libressl')
makedepends=('cmake' 'doxygen' 'python' 'quilt')
source=("https://www.libssh.org/files/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/libs/libssh/libssh_${_debver}-${_debrel}+deb11u1.debian.tar.xz")
sha512sums=('d7a1687d1e47a0a2b99c2a43fcfbf39c549b368711ad407a66257e8c2c258163c63dae5896d1c6918ade297f639d08c7948e7e4e9345cb9097e0aa5390154218'
            '847d44c1aa175fe117afa4d1ead1d6523343a8f52700281b2002ffe795bc8ae74fdc6b77ca2987765e1e5af1fab7c7180124e1ec9485c4c582c878643fbcdbca')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # disable the test. It is confused by our clean container setup.
  # 'extra-x86-build' uses user 'nobody' that has a record in /etc/passwd file
  # but $HOME envvar is set to '/build'. The test expects that $HOME corresponds to passwd file.
  sed 's/cmocka_unit_test(torture_path_expand_tilde_unix),//' -i tests/unittests/torture_misc.c
}

build() {
  cmake \
    -S $pkgname-$pkgver \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DWITH_GSSAPI=OFF \
    -DUNIT_TESTING=OFF
  make -C build
  make -C build docs
}

package() {
  make DESTDIR="$pkgdir" -C build install
  mkdir -p "$pkgdir"/usr/share/doc/$pkgname
  cp -r build/doc/html "$pkgdir"/usr/share/doc/$pkgname
  install -Dm644 "$srcdir"/$pkgname-$pkgver/COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}