# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libsoup
pkgver=2.74.3
_debver=$pkgver
_debrel=1
pkgrel=3
pkgdesc="HTTP client/server library"
url='https://wiki.gnome.org/Projects/libsoup'
arch=('i686' 'x86_64')
license=('LGPL-2')
depends=('glib2' 'libxml2' 'glib-networking' 'sqlite' 'krb5' 'libpsl')
makedepends=('gobject-introspection' 'python' 'vala' 'meson' 'quilt')
source=("https://download.gnome.org/sources/${pkgname}/${pkgver:0:4}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/libs/libsoup2.4/libsoup2.4_${_debver}-${_debrel}+deb12u1.debian.tar.xz"
        "CVE-2024-52531-1.patch")
sha512sums=('72f8a055df984cb35105fe67f4ca67d3fb110d40a9cacb660fccd89f93b06bc32e25d94375dcc76608a245f7c5e081d968d7aaf5952eb16013d81c741247cb4c'
            '411ac63e5ed7a62083d1a33e67887f96fccc30ed14c01e9a6e5c1b09a8b532e04d0594926ec143d10f02398bc894465bbad375aa16f56942b097cfa6d25a2172'
            '145e32799a1e9e2d3e97ecc605507ea7ca6d7191e155900ba156b1bedb518ea8e642399a91d39471eb2088e5316096a9d1a5bb2ddb51b912f1a0e46274289319')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/CVE-2024-52531-1.patch || true

    quilt push -av
  fi
  patch -Np1 -i ${srcdir}/CVE-2024-52531-1.patch
}

build() {
  hyperbola-meson $pkgname-$pkgver build -D gtk_doc=false -D ntlm=disabled -D sysprof=disabled -D brotli=disabled
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 $pkgname-$pkgver/COPYING -t $pkgdir/usr/share/licenses/$pkgname
}