# Maintainer: Jesus E. <heckyel@riseup.net>
# Contribute: Márcio Silva <coadde@hyperbola.info>

pkgname=libsndfile
pkgver=1.0.31
_debver=1.0.31
_debrel=1
pkgrel=2
pkgdesc="A C library for reading and writing files containing sampled audio data"
arch=('i686' 'x86_64')
url="https://libsndfile.github.io/libsndfile/"
license=('LGPL-2.1')
depends=('flac' 'glibc' 'libogg' 'libvorbis' 'opus' 'speex')
makedepends=('alsa-lib' 'cmake' 'libsndio' 'python' 'sqlite' 'quilt')
source=(https://github.com/${pkgname}/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.bz2{,.sig}
        https://deb.debian.org/debian/pool/main/libs/libsndfile/libsndfile_$_debver-$_debrel.debian.tar.xz
        sndio.patch)
sha512sums=('62202092e5cac6346fd3c0a977380e9bf888fc59d08c9c9707dc254a8ef6ed6356da2ab0430bb970c7b06ba5bb1dafa5d7b0fe13898834c1fe4acb16f409f0e1'
            'SKIP'
            '253bce54391694671d724333cbbeba1ef22ce724557ff3f622014d33ca22dfd51e6b9d2248b75f025a2ed78def8f38ffbb53bd7ade6e8f2d3f1b7e3689a7c7a7'
            '051dfa1e1d6fdd3de0c2a847c8131aeb31fae5fe9705af13c3e52a3d7b7df50a8b5c8843c0f803486e254c734cc05ecef68bc01a4b5163be8a48dd33d86af1b5')
validpgpkeys=('6A91A5CF22C24C99A35E013FCFDCF91FB242ACED'  # Erik de Castro Lopo <erikd@mega-nerd.com>
              '9B1CFD2E92239C4B288E025F9D0D1F1CCB35FF8C'  # evpobr evpobr@gmail.com
              '31D95CAB6D80D262244A1750A47620E801E47E95'  # David Seifert soap@gentoo.org
)

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  patch -p1 -i ../sndio.patch
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  # tests can only be built with static libs
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE='None' \
        -Wno-dev \
        -B build-test \
        -S .
  make VERBOSE=1 -C build-test

  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE='None' \
        -DBUILD_SHARED_LIBS=ON \
        -Wno-dev \
        -B build \
        -S .
  make VERBOSE=1 -C build
}

check() {
  cd "$pkgname-$pkgver"
  make test -C build-test
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install -C build
  install -vDm 644 {AUTHORS,ChangeLog,NEWS,README} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -vDm 644 COPYING \
    -t "${pkgdir}/usr/share/licenses/${pkgname}"
}