# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libsigc++
pkgver=2.10.4
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="Callback Framework for C++"
url='https://libsigcplusplus.github.io/libsigcplusplus/'
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=('gcc-libs' 'libxslt')
makedepends=('mm-common' 'meson' 'quilt')
options=(!emptydirs)
source=("https://download.gnome.org/sources/libsigc++/${pkgver:0:4}/libsigc++-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/libs/libsigc++-2.0/libsigc++-2.0_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('ced303312339b4598e57dcd4325c310cf96f907ff3de3ac3c03ba7849ef4c7e988896aab300252ec6b6af054eed092fdbe516aa8413d1569503ef1a67ab9b711'
            '7e9d22bfde3325b07dc7d8f01f1c77063edc314a22bfafc322c805d2fdbbbed7e72ad75e7743d571f52c060a338d4104dad48d9f7d5555b05413833b87642120')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  hyperbola-meson $pkgname-$pkgver build -D maintainer-mode=true -D build-documentation=false
  ninja -C build
}

package() {
  provides=("libsigc++2.0=${pkgver}")
  replaces=('libsigc++2.0')
  conflicts=('libsigc++2.0')

  DESTDIR="$pkgdir" meson install -C build

  install -Dm644 $srcdir/$pkgname-$pkgver/COPYING -t $pkgdir/usr/share/licenses/$pkgname
}