# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libots
pkgver=0.5.0
_debver=0.5.0
_debrel=6
pkgrel=1
pkgdesc='Open Text Summarizer'
url='https://libots.sourceforge.net/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('libxml2' 'glib2' 'popt')
makedepends=('quilt')
source=("https://deb.debian.org/debian/pool/main/o/ots/ots_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/o/ots/ots_${_debver}-${_debrel}.debian.tar.xz"
        "remove-gtk-doc.patch")
sha512sums=('736a672e16b741f2948e6874b88d4ade8e0450941915e65285f2fe661194a6d384a6abb267b15c3254c638750c644b4b2cf4279d7bda163b02336fcd8da9cfbe'
            'd905bc2c92b174fe2f0ca07e5a5a6c6926cb4d8ddc3d79525cbd27938d0b0b9a278e669dcc39090423bd96cbcbf3397e60dbc34c92fb0dbbba10a3740202a6fd'
            '0e39c88898444d7643ee17eddca5e7055bef88b2784f77611ed725acaee5843376ea271ebfcacaa6bb9dcc57d1e54d68bf7f80d735f2817eff14fb42fafb9085')

prepare() {
  cd ots-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/gtkdoc.patch || true

    quilt push -av
  fi

  # additional fixes
  patch -Np1 -i ../remove-gtk-doc.patch

  autoreconf -vfi
}

build() {
  cd ots-${pkgver}
  ./configure --prefix=/usr --disable-gtk-doc

  make
}

package() {
  cd ots-${pkgver}
  make DESTDIR="${pkgdir}" install

  # license
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}