# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libnids
pkgver=1.25
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="An implementation of an E-component of Network Intrusion Detection System."
arch=('i686' 'x86_64')
url='http://libnids.sourceforge.net/'
license=('GPL-2')
depends=('libnet' 'libpcap' 'glib2' 'libnsl')
makedepends=('pkgconfig' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/libn/${pkgname}/${pkgname}_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/libn/${pkgname}/${pkgname}_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('8f89b0e26759d54b139c1a77a5ec45fe5437d88cc4db718d4f77c2fa741aec7bd82e1dcfc8402d47acbc037c1e32b35f709bce316e47a15b5d20d8beb16fe830'
            '43fe1db3cfc19cd60aae0c15f421c1eca407b5f00730731c65300d1561b4c9f384b69a071f867473d3f668b3dce0c24e655225158574d6649512e317cf2c9de7')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/04_avoid-soname-bump.patch || true

    quilt push -av
  fi
}

build() {
  cd "$srcdir"/$pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --man=/usr/share/man \
    --enable-shared
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver

  make install_prefix="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}