# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libnatpmp
pkgver=20150609
_debver=20150609
_debrel=7.1
pkgrel=1
pkgdesc='A portable and fully compliant implementation of the NAT-PMP protocol'
arch=('i686' 'x86_64')
url='http://miniupnp.free.fr/libnatpmp.html'
license=('Modified-BSD')
depends=('glibc')
makedepends=('quilt')
source=("https://miniupnp.tuxfamily.org/files/libnatpmp-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libn/libnatpmp/libnatpmp_$_debver-$_debrel.debian.tar.xz")
sha512sums=('e50b1f68ce9254bb2f068ddc37417a3c417b80f7b3fb3d84e3e9af4a144d89e204ab993b54c01657335e855d0124a8fcbbf96ce78db7b9ae0b03b6eb79de2e09'
            'cd38c4b3a5b412c7f51f0cadfc9cf3f2f7f0959ffd15c6fecf784dad4d3a04d39579798bd6ee1a8d10925800cf67c4d181e771fdf2d53ce6c2b855a409bfe0f1')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  sed -e 's/CFLAGS = /CFLAGS += /' -i Makefile
}

build() {
  cd $pkgname-$pkgver
  make
}

package() {
  cd $pkgname-$pkgver
  make INSTALLPREFIX="$pkgdir/usr" INSTALLDIRINC="$pkgdir/usr/include" install
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  install -Dm644 natpmpc.1 "$pkgdir/usr/share/man/man1/natpmpc.1"
}