# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=mypaint
pkgname=lib$_pkgname
# this version is a 1.6.0 with fixes only, doen't need debian patches (package revised)
pkgver=1.6.1
pkgrel=4
pkgdesc="Library for making brushstrokes which is used by MyPaint and other projects"
url='https://mypaint.app/'
arch=('i686' 'x86_64')
license=('ISC')
depends=('gegl' 'json-c')
makedepends=('doxygen' 'gobject-introspection' 'intltool' 'python' 'gettext-tiny')
optdepends=('gobject-introspection: gir bindings')
source=("https://github.com/${_pkgname}/${pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('f759223e2e2da9fcc675bc2fa6324e2688ab36bdd979c0b3fad6737a6884e6095b6599c37960fd4897b9fd9063d5643fc2ab7e559438095c1872e019cd46d38b')

prepare() {
  cd $pkgname-$pkgver
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-gegl \
    --enable-docs
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}