# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libkeybinder3
pkgver=0.3.2
_debver=$pkgver
_debrel=1.1
pkgrel=2
pkgdesc="A library for registering global keyboard shortcuts"
arch=('i686' 'x86_64')
url="https://github.com/engla/keybinder/tree/keybinder-3.0"
license=('Expat')
depends=('gtk')
makedepends=('gobject-introspection' 'mesa-libgl' 'quilt')
optdepends=('lua-lgi: lua bindings')
source=("https://github.com/kupferlauncher/keybinder/releases/download/keybinder-3.0-v$pkgver/keybinder-3.0-${pkgver}.tar.gz"{,.sig}
        "https://deb.debian.org/debian/pool/main/k/keybinder-3.0/keybinder-3.0_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('14171875e03ade88165f28c7267b66cf9efe34259d7a3072a786ba49dacf8f8d6d84753b1aeedec5dfb0a24028be86bceeebee2f6b1bf5ef2eb79ee45f909b11'
            'SKIP'
            'e9da66b66af6fac4da958c4aab72d2c08b4c0a53fc396bdc0c15ca64d7906c48810f8e64ef48819eb429b20ec6fd84023d35095a68031d1fc482628a6ef3ecbf')
validpgpkeys=('2578ABA1F9023159DFF211B7368712C4D7A44445') # Ulrik Sverdrup <ulrik.sverdrup@gmail.com>

prepare() {
  cd keybinder-3.0-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd keybinder-3.0-$pkgver
  ./configure \
    --prefix=/usr \
    --disable-gtk-doc
  make
}

package() {
  cd keybinder-3.0-$pkgver
  make DESTDIR="$pkgdir" install

  # we don't support gtk-doc
  rm -rf $pkgdir/usr/share/gtk-doc

  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}