# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libkate
pkgver=0.4.1
_debver=0.4.1
_debrel=11
pkgrel=6
pkgdesc="A karaoke and text codec for embedding in ogg"
url="https://wiki.xiph.org/OggKate"
license=('Modified-BSD')
arch=('i686' 'x86_64')
depends=('libpng' 'libogg')
makedepends=('quilt')
source=("https://deb.debian.org/debian/pool/main/libk/libkate/libkate_$pkgver.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/libk/libkate/libkate_$_debver-$_debrel.debian.tar.xz"
        0001-Fix-automake-warnings.patch)
sha512sums=('2635237753abc0f6c43fc07bd0ecc57c2f3c893efa6c62ad08de9191045612477302ed45acd61cdfea7447efd654ebbe0ed2d6a2cbf867eb834581d7ee43377b'
            '8ee09457110a76881183001865392a5f908913a47c32ba6c091dacdefc10e826621526d3e809c3cc5d49aa69de92bd37c72076ec0f0abe6e75a2f1c660e28b7a'
            '525d120cddd040441859f2783e6e566da631ba304074bfa40a34399879fc3053577e8e71ef804168aeef519fac62e205829b50a61d770cddd46f7dbfba660842')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  else
    patch -Np1 -i ../0001-Fix-automake-warnings.patch
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
              --disable-static \
              --disable-doc
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 COPYING
  rm "${pkgdir}/usr/share/man/man1/KateDJ.1"
}