# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libisofs
pkgver=1.5.2
_debver=1.5.2
_debrel=1
pkgrel=1
pkgdesc="Library to pack up hard disk files and directories into a ISO 9660 disk image"
arch=('i686' 'x86_64')
url="https://dev.lovelyhq.com/libburnia"
license=('GPL-2')
depends=('acl' 'zlib')
source=(https://files.libburnia-project.org/releases/${pkgname}-${pkgver}.tar.gz{,.sig}
        https://deb.debian.org/debian/pool/main/libi/libisofs/libisofs_$_debver-$_debrel.debian.tar.xz)
sha512sums=('65048f2e33e96091ebce5b432ea607242050a3561c8eac18364bbe966d38c4f12ac1f4b38da5ea95ad4414f2b79b5fca99c1c0827e754bbbf6f7668d7e2c2bab'
            'SKIP'
            'a015a7b1463e3d190fd7ecde33b2c35f3ec36c2f705dc49ab65dd32fbd7e8e8ad23659acaaf42cb1ae7df3f95f77f90bf4cf59449cd64589de6b32607e92234c')
validpgpkeys=('44BC9FD0D688EB007C4DD029E9CBDFC0ABC0A854') # Thomas Schmitt <scdbackup@gmx.net>

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/01-switch-to-libjte2.patch || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
	--enable-libacl --enable-xattr --disable-static
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install

  for i in COPYING COPYRIGHT; do
    install -Dm644 ${i} ${pkgdir}/usr/share/licenses/${pkgname}/${i}
  done
}