# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libgnomecanvas
pkgver=2.30.3
_debver=$pkgver
_debrel=4
pkgrel=1
pkgdesc="Canvas library"
url='https://www.gnome.org'
arch=('i686' 'x86_64')
license=('LGPL-2')
depends=('libglade' 'libart')
makedepends=('pkg-config' 'intltool' 'python' 'quilt')
source=("https://download.gnome.org/sources/${pkgname}/2.30/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/libg/libgnomecanvas/libgnomecanvas_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('b5bfa2133f5172abd5228d467db4d980dd4ac125cdbf55dcc1d5055dc3330861320c12cccb52ea63ba7f69824504c9d25781cd78001dc7a92b11c6f7e0c550de'
            'e05e6103b7a04a9bf9d7c3030d0bbc081ca8c8a3118a0a52952731fae8826626ff8562671a8473f7434ea49080a8fd06df437d873dd58e0f038f50405f661101')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr \
    --disable-static \
    --enable-glade

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING.LIB -t "${pkgdir}/usr/share/licenses/$pkgname"

  # cleanup
  rm -rf "${pkgdir}/usr/share/gtk-doc"
}