# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libglade
pkgver=2.6.4
_debver=2.6.4
_debrel=2.3
pkgrel=1
pkgdesc='Allows you to load glade interface files in a program at runtime'
url='https://gnome.org/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('gtk2' 'libxml2')
makedepends=('tauthon' 'pkgconfig')
install=glade.install
source=(https://download.gnome.org/sources/${pkgname}/2.6/${pkgname}-${pkgver}.tar.bz2
        https://deb.debian.org/debian/pool/main/libg/libglade2/libglade2_$_debver-$_debrel.debian.tar.xz)
sha512sums=('b725842febaf4c1f0d305a629ae1c61ea2de24dd6f41937e806c078fada2cea483195ef40f5238ce2045e47130c92559e984f677de667b840dd7fff0f8559735'
            '328c47c6e4e8579c0f28e136dec791475f893b0e51e9ec6fca1bad1de4edbf0ba0a4dbc4485d5510b12f2b8e68c43a1b8864748add80c2f52f5c98e31bcfa04a')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  PYTHON=/usr/bin/tauthon ./configure --sysconfdir=/etc --prefix=/usr --localstatedir=/var

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  rm -r "$pkgdir/usr/share/gtk-doc"
  install -m755 libglade-convert "${pkgdir}/usr/bin/"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}