# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libgit2
pkgver=1.7.2
_debver=$pkgver
_debrel=1
pkgrel=1
epoch=1
pkgdesc="A linkable library for Git"
arch=('i686' 'x86_64')
url='https://libgit2.github.com/'
license=('custom:GPL-2+with-linking-exception' 'Simplified-BSD' 'GPL-2' 'Public-Domain' 'Modified-BSD' 'Expat' 'LGPL-2.1' 'ISC' 'CC0-1.0')
depends=('glibc' 'http-parser' 'libressl' 'pcre' 'zlib')
makedepends=('cmake' 'libssh2' 'python' 'quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/libgit2/libgit2/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libg/libgit2/libgit2_${_debver}+ds-${_debrel}.debian.tar.xz")
sha512sums=('825737e4a1991fba50ea535f15b0e560ebe76ead752e04aeba36925b944d0da77fe9826a70980a1aa3d0bf9afbedfab79dd92e799c9252931384c89ebec9b012'
            '85426848ff9acdbec6fbaf41669cddb827308ae091c8ae85edd462829c4ec21b3e4e761f991e4dd0d151687de3532bc4f0d5b6225916f82c90eaa3f877177d95')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}


build() {
  cmake \
    -S $pkgname-$pkgver \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE='None' \
    -DUSE_HTTP_PARSER=system \
    -Wno-dev
  make -C build
}

package() {
  make -C build DESTDIR="$pkgdir" install

  cd "$pkgname-$pkgver"
  install -Dm644 {AUTHORS,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname/
}