# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libesmtp
pkgver=1.0.6
_debver=1.0.6
_debrel=4.3
pkgrel=1
pkgdesc='A library to manage posting mail to a preconfigured MTA.'
arch=('i686' 'x86_64')
url='http://www.stafford.uklinux.net/libesmtp/'
license=('LGPL-2.1')
depends=('libressl')
makedepends=('quilt')
source=("https://deb.debian.org/debian/pool/main/libe/libesmtp/libesmtp_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/libe/libesmtp/libesmtp_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('2b0fd42d66800c4d3315b6e6b152cf427a7ef3656fc1269799d1697cba3bd07594e8346dacfd18ee74a71cb80a793f75449be236aa3319ef53c70a51c4eb2bc3'
            '69a5860b1b8f556b72a9015fb45b0f2cdb2947b20e0683c5df70d4ba8284de1efac00475703425b6d6776d1cc1e639fe6c4973a817805783e7d485186a2ea130')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING.LIB -t "$pkgdir"/usr/share/licenses/$pkgname
}