# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libdbi-drivers
pkgver=0.9.0
_debver=$pkgver
_debrel=9
pkgrel=2
pkgdesc="Database drivers for libdbi (PostgreSQL and SQLite)"
url='http://libdbi-drivers.sourceforge.net/'
license=('LGPL-2.1')
arch=('i686' 'x86_64')
depends=('libdbi')
makedepends=('postgresql-libs' 'sqlite' 'quilt')
optdepends=('postgresql-libs: To work with PostgreSQL using libdbdpgsql'
            'sqlite: To work with SQLite using libdbdsqlite3')
source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libd/libdbi-drivers/libdbi-drivers_$_debver-$_debrel.debian.tar.xz")
sha512sums=('f4d3aaa71014697c53012a10bf9f0af398bcf5ee5872af165f8f43a682d2fb3045a9172ffea0e068dcbfcad52494878c037d8d90fadfaf176936e42f7f1e85c1'
            '95a81900ba9e690e29ee8a0ae3b27888d826b74294152118bea06aef4624cde1f9e8e707d142097107c184ab4941642294b72986147438b6053dd0ccc99ccbf2')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --localstatedir=/var \
    --disable-docs \
    --without-mysql \
    --with-pgsql \
    --with-sqlite3
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}