# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libcue
pkgver=2.2.1
_debver=$pkgver
_debrel=4
pkgrel=2
pkgdesc="Parses so-called cue sheets and handles the parsed data"
url='https://github.com/lipnitsk/libcue/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('glibc')
makedepends=('cmake' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/lipnitsk/libcue/archive/v${pkgver}.tar.gz"
        "https://security.debian.org/debian-security/pool/updates/main/libc/libcue/libcue_${_debver}-${_debrel}+deb12u1.debian.tar.xz")
sha512sums=('32e476cb09ed2cb2d64aaba1342fb91e77e448391b493a3a794a8d2a6723a0e6097a90b11c6ad82998cb7f270f4f18c2578d7b8575f6929c2a35502e09ebc964'
            '30ca81473732bd74be49a9b64ee78762511527465dcb676920eb094de9689e3973eb671958a9e21e9afa4cee121ac39426885ba10aba008890f3402fc4c75568')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake \
    -S "${pkgname}-${pkgver}" \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_SHARED_LIBS=ON .
  make -C build
}

package() {
  make DESTDIR="${pkgdir}" -C build install
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/"LICENSE -t ${pkgdir}/usr/share/licenses/${pkgname}
}