# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libcaca
pkgver=0.99.beta19
_debver=$pkgver
_debrel=2.1
pkgrel=3
pkgdesc="Color AsCii Art library"
arch=('i686' 'x86_64')
license=('WTFPL-2.0' 'LGPL-2.1')
url='http://caca.zoy.org/wiki/libcaca'
depends=('imlib2' 'ncurses')
makedepends=('quilt')
options=(!emptydirs)
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/libc/libcaca/libcaca_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/libc/libcaca/libcaca_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('780fc7684d40207cc10df3f87d6d8f1d47ddfffa0e76e41a5ce671b82d5c7f090facb054c3d49ca7c4ea1a619625bb9085ce52f837f50792b4a2d776a4c68e15'
            '5635351db67126be7d9b215c8b224e3ff5fa08333fa95d1c560840a056c048c83203d17d9412068740e352e106bb49a7f3ce1552bc0ec9372bf4a5a3e3dae5f5')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --enable-shared \
    --disable-doc \
    --disable-cxx \
    --disable-gl \
    --disable-csharp \
    --disable-static
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  for i in COPYING{,.LGPL}; do
    install -Dm644 ${i} "${pkgdir}/usr/share/licenses/libcaca/${i}"
  done
}