# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libburn
pkgver=1.5.2 #.pl01
_debver=1.5.2
_debrel=1
pkgrel=1
pkgdesc="Library for reading, mastering and writing optical discs"
arch=('i686' 'x86_64')
url="https://dev.lovelyhq.com/libburnia"
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
source=(https://files.libburnia-project.org/releases/${pkgname}-${pkgver}.tar.gz{,.sig}
        https://deb.debian.org/debian/pool/main/libb/libburn/libburn_$_debver-$_debrel.debian.tar.xz)
options=('!emptydirs')
sha512sums=('a8887907bbfcd9b743dfc2e8924cc9290d7af5a71651aeabfdc5874f2df076278ccdbc94f81efd6a720972f380512d330576739837ba685055ee717dd74797d3'
            'SKIP'
            'fc18d72287042d2631621d3650ac3425133ba3fa9b97ebc2e40ec79c472ad665e5a8b8bd71cf59fe63e40a838f9d7a5fe6a0eda9f52c5a2f41770cba1fbfa971')
validpgpkeys=('44BC9FD0D688EB007C4DD029E9CBDFC0ABC0A854') # Thomas Schmitt <scdbackup@gmx.net>

prepare() {
  cd ${pkgname}-${pkgver/.pl01/}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver/.pl01/}
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd ${pkgname}-${pkgver/.pl01/}
  make DESTDIR=${pkgdir} install

  for i in COPYING COPYRIGHT; do
    install -Dm644 ${i} ${pkgdir}/usr/share/licenses/${pkgname}/${i}
  done

  # Make symlinks for cdrkit/cdrtools/dvdrtools compatibility
  ln -s cdrskin $pkgdir/usr/bin/cdrecord
  ln -s cdrskin $pkgdir/usr/bin/dvdrecord
  ln -s cdrskin $pkgdir/usr/bin/wodim

  ln -s cdrskin.1.gz $pkgdir/usr/share/man/man1/cdrecord.1.gz
  ln -s cdrskin.1.gz $pkgdir/usr/share/man/man1/dvdrecord.1.gz
  ln -s cdrskin.1.gz $pkgdir/usr/share/man/man1/wodim.1.gz
}