# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libao
pkgver=1.2.2
pkgrel=2
pkgdesc='Cross-platform audio output library and plugins'
url='https://xiph.org/ao/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('alsa-lib' 'libsndio')
optdepends=('sndio: sndio audio backend')
backup=('etc/libao.conf')
source=("$pkgname-$pkgver.tar.gz::https://github.com/xiph/$pkgname/archive/$pkgver.tar.gz"
        'libao.conf'
        '0001-Check-memory-allocations-for-success.patch'
        '0002-ao_example-free-buffer.patch'
        'patch-src_plugins_sndio_ao_sndio_c.patch')
sha512sums=('d2736d25b60862e7d7469611ce31b1df40a4366ab160e2ff1b46919ae91692d1596c8468e4f016303b306fc3ac1bddc7b727f535a362f403c3fe7c6532e9045a'
            '7064b123b0a4827241e1554752344b97202d5d5c9522c5e126aba25548e3218237828aa2e5fa5b4c2d0354833bf15f894d189372a82e7cc96d395cfcbc9bd323'
            '09bc3b90a6403563d2b9628aa81210e41c2935b0141fb164be60c6b82a38a16cc4f6a307df2d543d5001a740757e78de9778f8342aaeae9a8a57a190e2cdb753'
            'e5a95c772a66f7631c6f7cf9d6872b1e867836599b548076d8ec689363cee4649b3234b41e2e553905c2223434dba632ae064eafb4ce1a2e6c04c7626ca687be'
            '4753de36a6a222e1dd6fc3e0ff38950373b2c53c22905724e1c8db4fa799ef0c34115f4e7b7e438622e2dd5be619de6585776f2946888a4bede45612478ca23a')

conflicts=('libao-pulse')
provides=("libao-pulse=${pkgver}-${pkgrel}")
replaces=('libao-pulse')

prepare() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	patch -p1 -i ../0001-Check-memory-allocations-for-success.patch
	patch -p1 -i ../0002-ao_example-free-buffer.patch
	patch -p0 -i ../patch-src_plugins_sndio_ao_sndio_c.patch
	./autogen.sh
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	./configure \
		--prefix=/usr \
		--enable-alsa-mmap \
		--disable-pulse

	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	make DESTDIR="${pkgdir}" install
	install -Dm644 "${srcdir}"/libao.conf "${pkgdir}"/etc/libao.conf
	install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
}