# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lftp
pkgver=4.9.2
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Sophisticated command line based FTP client"
arch=('i686' 'x86_64')
url='https://lftp.yar.ru/'
license=('GPL-3')
depends=('gcc-libs' 'readline' 'gnutls' 'expat' 'sh' 'hicolor-icon-theme')
makedepends=('quilt')
optdepends=('perl: needed for convert-netscape-cookies and verify-file')
backup=('etc/lftp.conf')
source=("https://lftp.yar.ru/ftp/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/l/lftp/lftp_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('cda8698e7e34d748715a6fe5dc06c758240302621c7957402f0cc67577acf1a96b436fda4282408dee8171dc84a31e0be432df99a30f0a10057a8e7ea9ec64ad'
            'c50e5e8482b02a8d2f65759f37a12bb2038180651e8d641b3e5c14feb03f71d7d7518a597cfc44b1a6b025e60d17e673518167b0348edc56e0d95babc0aa9b19')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
    --with-gnutls \
    --without-openssl \
    --without-included-regex \
    --disable-static
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/lib
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}