# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=leptonica
pkgver=1.79.0
_debver=$pkgver
_debrel=1.1
pkgrel=2
pkgdesc="Software that is broadly useful for image processing and image analysis applications"
arch=('i686' 'x86_64')
url='http://www.leptonica.com/'
license=('Simplified-BSD')
depends=('giflib' 'libjpeg-turbo' 'libpng' 'libtiff' 'zlib')
makedepends=('quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/DanBloomberg/leptonica/archive/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/l/leptonlib/leptonlib_${_debver}-${_debrel}+deb11u1.debian.tar.xz")
sha512sums=('d7ade3b559ff7597117f6a798c4c9881877b412915fbf1732557c6ffb0d700ba769872ea3191acb7c7bfd85b40a41593ec3dc7d752b11b97281cea79d7d3fb63'
            'c22351bd19f933bfd64e25d921b1ac61e411e2f51f9cd6ca5434dec1cfb21bf88bf7783835316099e90c1f8d29b5199ec548dce2a8275e22b26b76df769f607a')

prepare() {
  cd "$srcdir"/leptonica-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  ./autogen.sh
}

build() {
  cd "$srcdir"/leptonica-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir"/leptonica-${pkgver}
  make DESTDIR="$pkgdir" install
  install -Dm755 leptonica-license.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}