# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ldb
pkgver=2.2.3
_debver=$pkgver
_debrel=2
pkgrel=1
epoch=1
pkgdesc="Schema-less, ldap like, API and database"
arch=('i686' 'x86_64')
url='https://ldb.samba.org/'
license=('GPL-3' 'LGPL-3' 'Expat' 'Modified-BSD')
depends=('talloc' 'tdb' 'popt' 'lmdb')
makedepends=('python' 'cmocka' 'docbook-xsl' 'tevent' 'quilt')
optdepends=('python: for python bindings')
source=(https://samba.org/ftp/${pkgname}/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/l/ldb/ldb_${_debver}-${_debrel}~deb11u2.debian.tar.xz)
sha512sums=('0fdda9e033cbd04d6b50c76ecf044068353d2abf50c5c9d9c804b8b9e70f6d85bf925ac984a38c2b7a159a384bfc94e5232b05a32cdbc9299dc43930d1b6a985'
            '35d7c3b6b623655d72cb3f8909d79a0c22c7db82ae748d1ea1dfe26b68b3375b8a3f757688712d575bfbf87f0611f06f9cc91a083e6d3392a1a38cafb2b876c2')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --disable-rpath \
    --disable-rpath-install \
    --bundled-libraries=NONE \
    --builtin-libraries=replace \
    --with-modulesdir=/usr/lib/ldb/modules \
    --with-privatelibdir=/usr/lib/ldb
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 debian/copyright -t "${pkgdir}/usr/share/licenses/$pkgname"
}