# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ladspa
pkgver=1.15
_debver=1.15
_debrel=2
pkgrel=1
pkgdesc="Sample tools for audio developer's simple plugin architecture"
arch=('i686' 'x86_64')
license=('LGPL-2.1')
url="https://www.ladspa.org/"
depends=('gcc-libs')
makedepends=('quilt')
source=("https://ladspa.org/download/ladspa_sdk_${pkgver}.tgz"
        "https://deb.debian.org/debian/pool/main/l/ladspa-sdk/ladspa-sdk_$_debver-$_debrel.debian.tar.xz"
        'fix-memleak-in-plugin-scanning.patch')
sha512sums=('a521622e23d988284244003e4ccfc3b42f6ddc7944cb00e7949b87e09d7f39a0cbb64b6d8b5a5af0a5ccf7179f88815416a88f02d3912957167e54b74accfc65'
            '686bef2ccfcbb4d83835150b26ae3090a1f898ac1e8ab2d75786e6f842803028508d861c522590a3c1743b2b9abceaa8331b7d301e4efc96d315aa4016f7abf3'
            'e80a575e6afe42f9d0ac1234a7832a29fb9362c7ab7b2d6b14cc3e6da6a9ba67af886cf09f1c0b78c161205084f705049fb4dc22fe2795efaeb7d94da90dc93e')

prepare() {
  mv -v ${pkgname}_sdk_${pkgver} ${pkgname}-${pkgver}
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/Allow-passing-FLAGS-to-make.patch

    quilt push -av
  fi
  patch -Np0 -i "../fix-memleak-in-plugin-scanning.patch"
  # add LDFLAGS for full RELRO
  sed -e "s#-O2#${CFLAGS} ${LDFLAGS}#" -i src/Makefile
}

build() {
  cd "${pkgname}-${pkgver}/src"
  make targets
}

package() {
  cd "${pkgname}-${pkgver}/src"
  make INSTALL_PLUGINS_DIR="${pkgdir}/usr/lib/ladspa/" \
       INSTALL_INCLUDE_DIR="${pkgdir}/usr/include/" \
       INSTALL_BINARY_DIR="${pkgdir}/usr/bin/" install
  install -vDm 644 ../doc/*.{html,txt} -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -vDm 644 ../doc/COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}