# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=kcgi
pkgver=0.13.4
_realpkgver=0_13_4
pkgrel=1
pkgdesc="Minimal CGI and FastCGI library"
arch=('i686' 'x86_64')
url='https://kristaps.bsd.lv/kcgi/'
license=('ISC')
depends=('glibc')
makedepends=('bmake' 'libseccomp' 'libmd')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/kristapsdz/kcgi/archive/refs/tags/VERSION_${_realpkgver}.tar.gz")
sha512sums=('53acccc5ad59958c359f1c46a5e08a66926d06f6adb9096226a197ed7334c556de9a4af8e0c292090884747cc42762ef1d810e2824daaa0041ba5568a153aea9')

prepare() {
  mv "${pkgname}-VERSION_${_realpkgver}" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"
  ./configure \
    PREFIX=/usr \
    MANDIR=/usr/share/man \
    SBINDIR=/usr/bin \
    LDFLAGS="$LDFLAGS"
  echo 'LDADD_LIB_SOCKET += $(LDFLAGS)' >> Makefile.configure

  # enable seccomp filter
  sed -i 's/#CPPFLAGS/CPPFLAGS/' Makefile
}

build() {
  cd "${pkgname}-${pkgver}"
  bmake
}

package() {
  cd "${pkgname}-${pkgver}"
  bmake DESTDIR="$pkgdir" install
  strip -x --strip-unneeded "$pkgdir/usr/bin/kfcgi"
  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
}