# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=kcaldav
pkgver=0.2.4
_realpkgver=0_2_4
pkgrel=1
pkgdesc="Simple, safe, minimal, free and libre CalDAV server"
arch=('i686' 'x86_64')
url='https://kristaps.bsd.lv/kcaldav/'
license=('ISC')
depends=('libbsd' 'sqlite' 'libmd')
makedepends=('expat' 'kcgi')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/kristapsdz/kcaldav/archive/refs/tags/VERSION_${_realpkgver}.tar.gz")
sha512sums=('00bef799af9334a2363789bd5df16f587d6c75ed8a7e2e9742efec946196f25848da661f40a664de6624d2f307d3f94c921cd4d035c47f518a7e69aaeaf039d8')

prepare() {
  mv "${pkgname}-VERSION_${_realpkgver}" "${pkgname}-${pkgver}"
}

build () {
  cd "${pkgname}-${pkgver}"
  ./configure PREFIX=/usr
  cat >> Makefile.configure <<-EOF
	CFLAGS += ${CFLAGS} $(pkg-config libbsd --cflags) \
		-include stdint.h -D_GNU_SOURCE -include errno.h
	LDFLAGS += ${LDFLAGS} $(pkg-config libbsd --libs)
	EOF
  make LDADD_STATIC=''
}

package () {
  cd "${pkgname}-${pkgver}"
  make install installcgi DESTDIR="${pkgdir}" \
    CGIPREFIX=/usr/lib/kcaldav \
    HTDOCSPREFIX=/usr/share/kcaldav

  # fix path for manual pages
  install -dm755 "${pkgdir}/usr/share/"
  mv "${pkgdir}/usr/man" "${pkgdir}/usr/share/"

  awk '/^\/\*/,/\*\// { print ; }' kcaldav.c > COPYING
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}