# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=itstool
pkgver=2.0.6
_debver=2.0.6
_debrel=1
pkgrel=1
epoch=1
pkgdesc="XML to PO and back again"
arch=(any)
url="http://itstool.org/"
license=('custom:GPL-3+OpenSSL-Linking-Exception')
depends=(python libxml2 docbook-xml)
makedepends=(quilt)
source=(http://files.itstool.org/itstool/itstool-$pkgver.tar.bz2
        https://deb.debian.org/debian/pool/main/i/itstool/itstool_$_debver-$_debrel.debian.tar.xz
        itstool-2.0.5-fix-crash-wrong-encoding.patch)
sha512sums=('51058bdcb208f6fb84810f71f9bf67e42b00bf157a9756be45f060849c0aff36f695f4403404193720d4446818fa77de61fa94eed9e8789d26c07a2926072eb7'
            'e308520969453b5ab6ab58d5fe6b7362d2c74ca386b9c77e16b53239e89fcf4c8b1dba110750bcf3de5dfee78f10e234910430fee510fd4448e3495ccfe7d0e0'
            '91c6b822c61f60d904960fc0c1b4d3b67c05540fe46d8738d834235eb9ecf6f7832585e741d4ac46021901f11fdc8624dd3ef42d9bd2901de99ab2b07ccd2cbc')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  else
    # From https://src.fedoraproject.org/rpms/libxml2/tree/master
    patch -Np1 -i ../itstool-2.0.5-fix-crash-wrong-encoding.patch
  fi

  autoreconf -fvi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  for i in COPYING{,.GPL3}; do
    install -Dm644 $i $pkgdir/usr/share/licenses/$pkgname/$i
  done
}