# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ispell
pkgver=3.4.02
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc='An interactive spell-checking program for Unix'
arch=(i686 x86_64)
url="https://www.cs.hmc.edu/~geoff/$pkgname.html"
license=('custom:Ispell')
depends=(ncurses)
makedepends=(byacc quilt)
source=(https://www.cs.hmc.edu/~geoff/tars/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/i/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz
        license.txt)
sha512sums=('4392c00d8bcc66a9cc521ef0ba6b06ada896925f7260b7712a65529719b331dab54de5298058c5d130ee52bd088d38ba5fcf7797f265a0f68514765574b966d4'
            '6d7323014860539c90f7c0f522da41a0ee736230bfe123821ba9dc235ff45cc66c1d4d74e70d0494c47526ff0841e12334e427a0380bd818b1a6fe7f3688150d'
            'c991ab91e629c35d1b84fc9e83b7738141b01612a7108b5a3f49f8f8606c2320727b1e6f2c1333ccaee0b942a126c699ca2ef72e84cb4bc3a1d0947c8a06fa27')
prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-Configuration.patch || true
    rm -v debian/patches/0003-Fix-FTBFS-on-Hurd.patch || true
    rm -v debian/patches/0010-Debian-control-file.patch || true
    rm -v debian/patches/0027-Include-Debian-Makefile.languages.inc.patch || true

    quilt push -av
  fi

  # Hotfix in generate "config.sh" file (bad Makefile code)
  touch config.sh
  chmod +x config.sh

  # Hotfix in languages build (to ignore prebuild files error; bad Makefile code)
  sed -i '\|eval| s|[$][(]MAKE[)]|$(MAKE) -i|' Makefile

  # Hotfix in package (to ignore prebuild directories error; bad Makefile code)
  sed -i  -e '\|mkdirpath| s|[$][(]MAKE[)]|$(MAKE) -i|' \
          -e 's|[$][(]MAKE[)][ ]EXEEXT[=][$][$]EXEEXT[ ]install|$(MAKE) -i EXEEXT=$$EXEEXT install|' \
    Makefile
}

build() {
  # Configure source code to built this package
  export CC=cc EXEEXT=
  pushd $pkgname-$pkgver
  cp -va local.h.linux local.h
  sed -i -e 's|bison[ ][-]y|yacc|' \
         -e "s|/usr/local|/usr|" \
         -e 's|/lib|/lib/ispell|' local.h
  popd

  make -C $pkgname-$pkgver all
}

package() {
  make DESTDIR=$pkgdir -C $pkgname-$pkgver install
  install -Dm644 license.txt -t $pkgdir/usr/share/licenses/$pkgname

  # correct package-structure
  mv $pkgdir/usr/man $pkgdir/usr/share
}