# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=irqbalance
pkgver=1.7.0
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="IRQ balancing daemon for SMP systems"
arch=('i686' 'x86_64')
url="https://github.com/irqbalance/irqbalance"
license=('GPL-2')
depends=('glibc')
makedepends=('glib2' 'libcap-ng' 'ncurses' 'numactl' 'quilt')
backup=('etc/conf.d/irqbalance'
        'etc/sv/irqbalance/conf')
source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/i/irqbalance/irqbalance_${_debver}-${_debrel}.debian.tar.xz"
        "irqbalance.confd"
        "irqbalance.initd"
        "irqbalance.conf"
        "irqbalance.run")
sha512sums=('2fa29c738275dda2fac38d78ca0ec4619826b72529e8eda7ad8ddcda5768bbf282e2260dddc16a8b46d4296289b25dc59684575ae1badca0c6c6ae30b1e9b5ea'
            'cd60361749688ce8e79a6f5b1013d21a3196e99ef0dcbcf044f1ae9dc7bdb74958a4b07d4a1c6e099fa6fd3ec3d436b5f306c41fdb8b25a860ccf7b07d02addb'
            '90e7ed187b4dccd6f6c4383ba54d6e1aed1645240e44aaf02db1b70b56594b1a828644d671e6db91212417981b1d5e53d1ecfd4b366496dbcb484d1064d7d24c'
            '88c3902015c6ce2d0ed2f1e41b0239c3ff68a14c4e1879c9670111d5ed7f7e37dc61915f109998527b74331ced06e48d42fc0b5c9185c2280f116706ae108b7e'
            '81ed47f44f5cf6717a3fd17576b4c5319a82d3dd6f2f36fdf62c01c19ce47c0b464daabe29aa70395cfa05ab92ee1e5b4a6eab709d7ccee2f0cee5e5257eeee1'
            '8561e9702c511a4c54e775044d9bc43ed89d0cc211307030b16201b8a714c1be8a874bdbce3925daa0304d70c5b5ae1f62baa61e7def6f4f867c6cc14fb4f341')

prepare() {
  cd "$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make install DESTDIR="$pkgdir"

  # these are system manuals
  mv $pkgdir/usr/share/man/man1 $pkgdir/usr/share/man/man8
  for f in irqbalance irqbalance-ui; do
    mv $pkgdir/usr/share/man/man8/$f.1 \
      $pkgdir/usr/share/man/man8/$f.8
  done

  # service-configuration
  install -Dm0644 "$srcdir/${pkgname}.confd" "${pkgdir}/etc/conf.d/${pkgname}"
  install -Dm0755 "$srcdir/${pkgname}.initd" "${pkgdir}/etc/init.d/${pkgname}"
  install -Dm0644 "$srcdir/${pkgname}.conf" "${pkgdir}/etc/sv/${pkgname}/conf"
  install -Dm0755 "$srcdir/${pkgname}.run" "${pkgdir}/etc/sv/${pkgname}/run"

  # license
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}