# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=iftop
pkgver=1.0~pre4
_realpkgver=1.0pre4
_debver=$pkgver
_debrel=7
pkgrel=2
pkgdesc="Display bandwidth usage on an interface"
arch=('i686' 'x86_64')
url='http://www.ex-parrot.com/~pdw/iftop/'
license=('GPL-2')
depends=('libpcap' 'ncurses')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/i/iftop/iftop_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/i/iftop/iftop_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('abd74e8025bb82fef9ebab4997b1d018201a523d47c0128128ca37797490046538d74758dc4471735c22b890e5bd238ad6b2a30776d465138ede367cdd263d22'
            '2c7b83faab10c59d20c50ae7be1976d7226eb66a4be1bf872da3765223f9a2cefc064663ba94625eba31eafed1c940e043be4ed9888e6e568effb1abce12371d')

prepare() {
  cd $pkgname-$_realpkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$_realpkgver
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man
  make
}

package() {
  cd $pkgname-$_realpkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}