# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=idesk
pkgver=0.7.5
pkgrel=1
pkgdesc="Free and libre program to show icons on the desktop"
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/idesk/'
license=('GPL-2' 'Modified-BSD')
depends=('pkgconfig' 'imlib2' 'libpng' 'libxpm' 'libxft' 'gcc-libs')
source=("https://downloads.sourceforge.net/sourceforge/idesk/$pkgname-$pkgver.tar.bz2"
	"imlib2-config.patch")
sha512sums=('42c15cecc6e2cf6546420542fc4480902fd33c26c19ffc32e65eb04d09116d3b80f5539cde4ca86d4bec30ce96417752bfe7416ec83c531235d9064d06ec0475'
            '2397d451861d9b1c61bceba3b5c23a649d83115b25c46ff88fe4c45166c4334c33a6d59a5adc7ea27395de6f0052aa3dc140ecd9b6374d8d551d278f3a48b6b9')

prepare() {
  cd $pkgname-$pkgver
  sed -i \
    -e '1,1i#include <unistd.h>' \
    -e '1,1i#include <sys/stat.h>' \
    -e '1,1i#include <sys/types.h>' \
    src/DesktopConfig.cpp
  sed -i 's/return iconConfigList\[++iterCtr\];/return ++iterCtr < iconConfigList.size() ? iconConfigList\[iterCtr\] : NULL;/' src/AbstractClasses.h
  sed -i 's#usr/local#usr#' examples/default.lnk
  patch -Np2 -b -z .orig <../imlib2-config.patch
  autoreconf -fiv
  sed -i \
    -e 's#IMLIB2_LIBS=.*#IMLIB2_LIBS=-lImlib2#g' \
    -e 's#IMLIB_LIBS=.*#IMLIB_LIBS="-L/usr/lib -Wl,-O1,--sort-common,--as-needed,-z,relro -ljpeg -ltiff -lgif -lpng -lz -lm -lXext -lXext -lX11 -lImlib2"#g' \
    configure
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}