# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=hunspell
pkgver=1.7.0
_debver=$pkgver
_debrel=3
pkgrel=2
pkgdesc="Spell checker and morphological analyzer library and program"
arch=('i686' 'x86_64')
url='https://hunspell.github.io/'
license=('GPL-2' 'LGPL-2.1' 'MPL-1.1')
depends=('gcc-libs' 'readline')
makedepends=('quilt')
optdepends=('perl: for ispellaff2myspell')
source=($pkgname-$pkgver.tar.gz::https://github.com/hunspell/hunspell/archive/v${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/h/hunspell/hunspell_$_debver-$_debrel.debian.tar.xz)
sha512sums=('8149b2e8b703a0610c9ca5160c2dfad3cf3b85b16b3f0f5cfcb7ebb802473b2d499e8e2d0a637a97a37a24d62424e82d3880809210d3f043fa17a4970d47c903'
            '305e5062ee19f79fbd16ccb2f699066f5eda70bc036ebadd2fa3fbf58ac9c2f89e71d18e2019a34c415b90a653748a971f41e11e83fc250129e0723e7a3d6fdf')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --disable-static \
    --with-ui \
    --with-readline
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # add generic hunspell.so for development and projects not using pkgconfig flags
  pushd "$pkgdir"/usr/lib
  ln -s libhunspell-?.?.so libhunspell.so
  popd

  for i in COPYING*; do
    install -Dm644 $i -t $pkgdir/usr/share/licenses/$pkgname
  done
}