# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=html2text-cpp
_pkgbase=html2text
pkgver=1.3.2a
_debver=$pkgver
_debrel=28
pkgrel=1
pkgdesc="A C/C++ based HTML to text converter"
arch=('i686' 'x86_64')
url='https://github.com/grobian/html2text'
license=('GPL-2')
depends=('gcc-libs')
makedepends=('quilt')
source=("https://deb.debian.org/debian/pool/main/h/html2text/html2text_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/h/html2text/html2text_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('8ec2c17849615b8b78b6f7e9066e5bcfb419b293ffe98323ed0942e891993e205ef37ddfd2839eb12b6bad561989027aea0ba2d57eb7193d424715f93ded90e5'
            '044b561c7990582fa5767632b5cf20f1849e14b37d2d0cb8d07e8d91a7ffc0086a8d38e8188736fe5017240b985c5d035284ccdc1f178e803aaf30549c5f1e13')

prepare() {
  cd ${_pkgbase}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${_pkgbase}-${pkgver}

  ./configure \
    --prefix=/usr
  make
}

package() {
  cd ${_pkgbase}-${pkgver}

  install -Dm755 $_pkgbase "${pkgdir}/usr/bin/$pkgname"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}