# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=hspell
pkgname=('hspell' 'hunspell-he-IL')
pkgver=1.4
_debver=$pkgver
_debrel=3.1
pkgrel=2
arch=('i686' 'x86_64')
license=('AGPL-3')
url='http://hspell.ivrix.org.il/'
makedepends=('glibc' 'zlib' 'perl' 'hunspell' 'gawk' 'quilt')
options=('!makeflags')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/h/hspell/hspell_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/h/hspell/hspell_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('d0c9205d9f6a7e9e2577b685418120542235d290ee8d95e2066694c45b4083e3ce1abc38c910714cde0941fa6b211522a8259b0d880a71c5b9c5a6d77a115f1a'
            'ce7fac8a59b0f05d8e1f25f1e77e00ce447aa3a99ef9c0055182fdd9ea69da5e7f054adfa0b96dbbdef0d910dea19a107ceaf8865755a9d1b2fac2f503b17b8a')

prepare() {
  cd ${pkgbase}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgbase}-${pkgver}
  export PERLLIB="$PWD"
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --enable-linginfo \
    --enable-fatverb \
    --enable-shared
  make
  make hunspell
}

package_hspell() {
  pkgdesc="Hebrew spell-checker"
  depends=('glibc' 'zlib' 'perl')

  cd ${pkgbase}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname/
}

package_hunspell-he-IL() {
  pkgdesc="Spell checking support for Hebrew (Israel)"
  groups=('hunspell-dictionaries')

  cd ${pkgbase}-${pkgver}
  install -dm755 "$pkgdir"/usr/share/hunspell
  install -m644 he.dic "$pkgdir"/usr/share/hunspell/he_IL.dic
  install -m644 he.aff "$pkgdir"/usr/share/hunspell/he_IL.aff

  # symlinks
  install -dm755 "$pkgdir"/usr/share/myspell/dicts
  pushd "$pkgdir"/usr/share/myspell/dicts
    for file in "$pkgdir"/usr/share/hunspell/*; do
      ln -sv /usr/share/hunspell/$(basename $file) .
    done
  popd

  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname/
}