# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=hexchat-legacy
_realpkgname=hexchat
pkgver=2.14.3
_debver=$pkgver
_debrel=6
pkgrel=1
pkgdesc="An easy to use graphical IRC (chat) client (legacy version)"
arch=('i686' 'x86_64')
url='https://hexchat.github.io/'
license=('GPL-2' 'Expat' 'LGPL-2.1')
provides=('hexchat')
conflicts=('hexchat')
depends=('desktop-file-utils' 'gdk-pixbuf2' 'glib2' 'gtk2'
         'libproxy' 'libressl' 'pango' 'pciutils')
makedepends=('intltool' 'iso-codes' 'lua' 'meson' 'perl' 'python-cffi' 'quilt')
optdepends=('enchant: Spell check'
            'iso-codes: Display language names instead of codes'
            'lua: Lua plugin'
            'perl: Perl plugin'
            'python-cffi: Python plugin')
source=("${_realpkgname}-${pkgver}.tar.gz::https://github.com/hexchat/hexchat/archive/refs/tags/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/h/hexchat/hexchat_${_debver}-${_debrel}+deb11u1.debian.tar.xz"
        "remove-defaults.patch")
sha512sums=('6ba007a67f47447def091e4615620c84beef8737b5f8015574557f644444ad4a2ac795622aeb831528a5ec1a9b387f0974dc30bbf6aafb53434953a941a97dfe'
            'ea111ea8c64a1c13af025a4b5bc037f350d8e5a2cff828c4f5dd4f99d28cd55808b6d6a5690086b065e2effe982b53b913c0442c84fda074facd1d4981b77895'
            '36b0e6927c8e62e7dad79559d76368fc35073376cbf215b76ac1800d8d012e0bcf89bdbd71eecbbabae17d8e14d4cb53ec37e0f9474257a051baf7c156950a3a')

prepare() {
  cd $_realpkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # we do not want some proposals for IRC-servers here
  # especially not hardcoded ones
  patch -Np1 -i ${srcdir}/remove-defaults.patch
}

build() {
  hyperbola-meson $_realpkgname-$pkgver build \
    -Dwith-lua='lua' \
    -Dwith-text='true' \
    -Dwith-libcanberra='false' \
    -Dwith-libnotify='false' \
    -Dwith-dbus='false'
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" ninja -C build install

  cd $_realpkgname-$pkgver
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}