# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gxkb
pkgver=0.9.0
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="X11 keyboard indicator and switcher"
arch=('i686' 'x86_64')
url='https://zen-tools.github.io/gxkb'
license=('GPL-2')
depends=('libxklavier' 'libwnck3' 'gtk')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/zen-tools/${pkgname}/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gxkb/gxkb_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('42861aac96cbedb0dc2392932d26a40ce5024e63c1b130bf0629d5593ffb57735ddc77fd1814fc2ab1a4e6838142c9d6b34fac038e87d1c4dcc3cf80dada6eca'
            '6b1b923a4f871f52feea1cc37ce11424ff98e5452b4a97061147a68269cd88562332aa7169a4a2c201e6a071ac3fbc9b99bc886a008721fbb3a77440f50daafa')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
  ./autogen.sh
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 doc/COPYING -t "${pkgdir}"/usr/share/licenses/$pkgname
}