# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gwenhywfar
pkgver=5.10.1
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="OS abstraction functions for various projects"
arch=('i686' 'x86_64')
url="https://www.aquamaniac.de/"
license=('custom:LGPL-2.1+OpenSSL-Linking-Exception')
depends=('gnutls' 'libgcrypt' 'libressl')
makedepends=('gtk' 'qt-base' 'quilt')
optdepends=('gtk: for the GTK+ UI'
            'qt-base: for the Qt UI')
source=("https://www.aquamaniac.de/rdm/attachments/download/465/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libg/libgwenhywfar/libgwenhywfar_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('11781bec2dd1c4156b609574283179278b8070d604a792aeddf92c8f9b873b3ac09273a8558b9adba567af8d016ea10914d2a149f4b6813798b5800e34e29aa5'
            'd61bef5a6e7d75b760a9ab3da913537628811dc56d12c277a28647558ccc79ba323f9d92c8897ff5d3e9a701aa314fb68580529dd9fdd6be05538ba3bfac87de')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-system-certs \
    --with-guis="gtk3 qt5"
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}