# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gumbo-parser
pkgver=0.10.1
_debver=0.10.1+dfsg
_debrel=2.4
pkgrel=1
pkgdesc='HTML5 parsing library in pure C99'
arch=('i686' 'x86_64')
url='https://github.com/google/gumbo-parser'
license=('Apache-2.0')
depends=('glibc')
makedepends=('quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/google/gumbo-parser/archive/v0.10.1.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gumbo-parser/gumbo-parser_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('bb1fb55cd07076ab6a9f38dc14db50397dbdca9a04ace4895dfba8b8cbc09038a96e26070c09c75fa929ada2e815affe233c1e2ecd8afe2aba6201647cf277d1'
            'c9c117603bef4862fab9481cd20c5f6ac2da1512341e3ed0bd6b4518b6fe03b9136269f9e349c8d140fd8392b9e9dd2536f2f98746807960e1487562fd79a446')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/00-tests.patch || true

    quilt push -av
  fi

  ./autogen.sh
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}