# Maintainer: Jesus E. <heckyel@riseup.net>
# Contributer (Arch): Ben <ben@benmazer.net>

pkgname=gtkspell2
_realpkgname=gtkspell
pkgver=2.0.16
pkgrel=1
pkgdesc="Provides word-processor-style highlighting and replacement of misspelled words in a GtkTextView widget"
url='http://gtkspell.sourceforge.net/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('gtk2' 'enchant')
makedepends=('intltool' 'gettext-tiny')
source=("https://downloads.sourceforge.net/sourceforge/gtkspell/${_realpkgname}-${pkgver}.tar.gz"
        "remove-gtkdoc.patch")
sha512sums=('7d3afb327c2e15608194e6ee6110107a0ce082e483788d831d636b2e579472304137373c09a966d8e5c0cd2f830bf2e0ee477c9b5fca7da6ee27fd1498915b9d'
            'af7daf44ee0c751ed4fd3fa830bb02f8d8caae4efa079854389f6fc8a1fb8d01091fd7417fc0bc0c62180bf2f592d943949ca2ec18d5deef13cac80f8c2b8406')

prepare() {
  cd "$_realpkgname-$pkgver"
  patch -Np1 -i ${srcdir}/remove-gtkdoc.patch
  rm gtk-doc.make
  rm -rf ./docs
  autoreconf -fvi
}

build() {
  cd "$_realpkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $_realpkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}