# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gsl
pkgver=2.6
_debver=2.6+dfsg
_debrel=2
pkgrel=1
pkgdesc="The GNU Scientific Library (GSL) is a modern numerical library for C and C++ programmers"
url="https://www.gnu.org/software/gsl/gsl.html"
license=('GPL-3')
arch=('i686' 'x86_64')
depends=('glibc')
makedepends=('quilt')
source=("https://ftp.gnu.org/gnu/gsl/$pkgname-$pkgver.tar.gz"{,.sig}
        "https://deb.debian.org/debian/pool/main/g/gsl/gsl_$_debver-$_debrel.debian.tar.xz")
sha512sums=('0be8240715f0b86aba2c63d9f12da4dba4719d4e350e9308d279e0dd3b2f0519ea26fd2e38a17f3e8cf43aacbaa2455207a7ca0d6c305f3b8725e8ece2250a74'
            'SKIP'
            'ca494e3ffd4d019303cee91cdb18286f6e4d18e6befc895a9869c6fa761c74051189ca3ef547321df6427c97609ee3ef0ee0311d1463184f312f57f32e268eb1')
validpgpkeys=(DD61B7FC02790F978360F399245FB74BAE05B3E9) # Patrick Alken <alken@colorado.edu>

prepare() {
    cd ${pkgname}-${pkgver}
    if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
      # Debian patches
      export QUILT_PATCHES=debian/patches
      export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
      export QUILT_DIFF_ARGS='--no-timestamps'

      mv "$srcdir"/debian .

      # Doesn't apply and seems unimportant
      rm -v debian/patches/reset-so-number || true

      quilt push -av
    fi
}

build() {
    cd ${pkgname}-${pkgver}
    ./configure --prefix=/usr
    make
}

check() {
    cd ${pkgname}-${pkgver}
    make check || true
}

package() {
    cd ${pkgname}-${pkgver}
    make DESTDIR="${pkgdir}" install
    install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}