# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=grsync
pkgver=1.3.1
pkgrel=1
pkgdesc="GTK+ GUI for rsync to synchronize folders, files and make backups"
arch=('i686' 'x86_64')
url='https://www.opbyte.it/grsync/'
license=('GPL-2')
depends=('gtk' 'rsync')
makedepends=('intltool' 'gettext-tiny')
source=(https://www.opbyte.it/release/$pkgname-$pkgver.tar.gz
        grsync.appdata.xml
        use-themed-icon.patch)
sha512sums=('af3e70108085ad240b8f692f4fd389e7df42448291b721e923fb7e7309e52a673a034583e68684820b47e520386c382efe56820da7b0e7146407bd3d09f2dc72'
            '501b9fd5d5a5033adf222116ff739f0b2743b53d988580a5a75581f7620ed5763be1cff1dc7bb885d51653454b84985b6f182c2e41ff3863812a5626068bff35'
            '00f349b07756ec85f7dac5ad6a8463ca68485b2d9a697942e944421f4e1c8e0765c3a7ae64d793a049de099b0046ad4525f9db45dfd2a97d892b2739da76a8c5')

prepare() {
  cd $pkgname-$pkgver

  # use themed icon
  patch -Np1 -i $srcdir/use-themed-icon.patch

  autoreconf -fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --disable-unity
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 ../$pkgname.appdata.xml "$pkgdir/usr/share/metainfo/$pkgname.appdata.xml"
  install -Dm0644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}