# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=gpicview
pkgname=('gpicview-gtk2' 'gpicview')
pkgver=0.3.1
pkgrel=1
pkgdesc="Lightweight image viewer"
arch=('i686' 'x86_64')
url='https://www.lxde.org/'
license=('GPL-2')
makedepends=('gtk' 'gtk2' 'gettext-tiny' 'intltool')
source=("${pkgbase}-${pkgver}.tar.gz::https://github.com/lxde/gpicview/archive/refs/tags/${pkgver}.tar.gz")
sha512sums=('15f6a3201067e0eb3b71492072f207e7b95e4c672cea358eca0bb71c404e9fd5e1e7d2fd28eda11965374c192a13b496f58fedea03799ea2b7aa80da66fcd812')

prepare() {
  cd $pkgbase-$pkgver

  # apply only one main category
  sed -i '/^Categories=/ s/Utility;//' gpicview.desktop.in

  autoreconf -fiv
}

build() {
  # GTK+ 2 version
  [ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
  cd gtk2
  ./configure \
    --prefix=/usr
  make

  cd "$srcdir"
  # GTK+ 3 version
  [ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
  cd gtk3
  ./configure \
    --prefix=/usr \
    --enable-gtk3
  make
}

package_gpicview-gtk2() {
  depends=('gtk2')
  conflicts=('gpicview')
  cd gtk2
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_gpicview() {
  pkgdesc+=' (GTK+ 3 version)'
  depends=('gtk')
  conflicts=('gpicview-gtk2')
  cd gtk3
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}