# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gphoto2
pkgver=2.5.27
_debver=2.5.27
_debrel=1
pkgrel=1
pkgdesc='A digital camera download and access program.'
arch=('i686' 'x86_64')
url='http://www.gphoto.org'
license=('GPL-2')
depends=('libgphoto2' 'popt')
makedepends=('quilt')
source=(https://downloads.sourceforge.net/gphoto/${pkgname}-${pkgver}.tar.bz2{,.asc}
        https://deb.debian.org/debian/pool/main/g/gphoto2/gphoto2_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('47001025d3647ac809ab7fd2d9319a2966d72b00471f9a9c865dfad7091c7cac2e299ecd41dfc7997a6665cf2612d4317591964f51a9d336f848e8199e3928b7'
            'SKIP'
            'ce98b00ea6e7ba845da3da2aa1306d37ad5efbcfdc951cc1efc79b05cd07789734333cbec5febe7ef2694245a1a214115e8b1d88b728471673afd1e84bba991e')
validpgpkeys=('7C4AFD61D8AAE7570796A5172209D6902F969C95')
validpgpkeys+=('') # "Marcus Meißner (german spelling) <meissner@suse.de>"

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/02-do_not_use_PATH_MAX.patch || true

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}