# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gpart
pkgver=0.3
_debver=$pkgver
_debrel=8
pkgrel=1
pkgdesc="Partition table rescue/guessing tool"
arch=('i686' 'x86_64')
url='https://github.com/baruch/gpart'
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/baruch/${pkgname}/archive/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gpart/gpart_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('5ee8bc551050d26dc71898d3232549d2b96e0806071571b120cbf819282da0ec2246147a0dfc44576e62d68092bb0183c1a9bb71db7ddca12c0922da60aeea35'
            '21362050fd35bc6badf1ecf13b0d9b94ee28994192beac47f438928c5b40399d54beca089b43b2a088cf8e82bfca6c9940c78bbd2a32657fc4c539bffdebe699')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  ./autogen.sh
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make prefix="${pkgdir}"/usr sbindir="${pkgdir}"/usr/bin install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}