# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gopchop
pkgver=1.1.8
_debver=$pkgver
_debrel=7
pkgrel=1
pkgdesc="Cut and merge MPEG2-PS files at GOP boundaries without reencoding."
url='http://outflux.net/unix/software/GOPchop/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('libmpeg2' 'libxml2' 'gtk2')
makedepends=('pkgconfig' 'intltool' 'quilt')
source=("https://downloads.sourceforge.net/project/gopchop/GOPchop%20-%20Development/1.1.8/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gopchop/gopchop_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('5c2af09415c3bc570fe72423912ce8e604031cf58fd1d3f0ef6c29f99994a919fb9f85a2af8635886d8043485cdddfd2652ae598ae218da41edab0c2043641a5'
            'a956b9bd47b3a11f3330eff31ceede6e5ba6e66e5948d935560dc8e7564b8dbd5f91b63fa8565ece927e375591f56518505cbb2821def85089650ccffb38ccb1')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  sed -i 's|.png||g' $pkgname.desktop
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}