# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=goffice
pkgver=0.10.55
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="A GLib/GTK+ set of document-centric objects and charting library"
url='https://git.gnome.org/browse/goffice'
arch=('i686' 'x86_64')
license=('GPL-3')
depends=('librsvg-legacy' 'gtk' 'libgsf' 'libspectre' 'libxslt' 'lasem')
makedepends=('intltool' 'gobject-introspection' 'autoconf-archive' 'quilt' 'automake')
source=("https://download.gnome.org/sources/goffice/0.10/goffice-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/g/goffice/goffice_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('c49eec867e4147102b54b70847b495cad0e55fcb069c78a8374760121219b9097c1dfb5601b240e92ed68a6fb785ab5e771f7c579dd138e106ee25a1b9ddfe99'
            '968a96b8537d9d64ea9145cfae1f1efa546747314691f89ded39be70afe51edaf4dc86439e1620a478bedefb2aef1a75ad4b16839ff3327f547faf61b749120f')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --disable-static \
    --enable-introspection \
    --disable-gtk-doc

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install

  # removing references towards gtk-doc
  rm -rf "${pkgdir}"/usr/share/gtk-doc

  # license
  install -Dm644 COPYING-gpl3 -t "${pkgdir}/usr/share/licenses/$pkgname"
}